#Get map ID
    execute unless score map option matches 1.. run scoreboard players set map option 1
    execute store result storage subchronos:input startingGame.mapID int 1 run scoreboard players get map option
    
    #Random
    execute if score map option matches 999 store result storage subchronos:input startingGame.mapID int 1 run random value 1..10
    execute if score map option matches 9999 store result storage subchronos:input startingGame.mapID int 1 run random value 1101..1105

    function subchronos:game/starting/load_map with storage subchronos:input startingGame

gamemode spectator @a
execute in minecraft:overworld run tp @a 1022.83 20.69 1023.66 91.10 90.00

team join player @a[tag=!spectating]
team join spectator @a[tag=spectating]

gamerule keep_inventory false
xp set @a 0 levels
xp set @a 0 points
effect clear @a
clear @a
scoreboard players reset * die

scoreboard players set gameStatus gameInfoValues 1
scoreboard players set .explosionFase temp 0

scoreboard players set startTime gameInfoValues 14
scoreboard objectives setdisplay sidebar gameInfo
scoreboard objectives setdisplay list gameKills
scoreboard players reset * gameKills

#Game id
    scoreboard players add .id gameID 1
    scoreboard players operation game gameID = .id gameID

    scoreboard players operation @a[tag=!spectating] gameID = .id gameID

##start button
scoreboard players set .startButtonStatus option 0
function subchronos:lobby/start_button/model/a/unpress/play