# Fireball Cooldown
    scoreboard players remove @a[scores={fireballCooldown=1..}] fireballCooldown 1

# Molotov
    execute as @e[type=area_effect_cloud,predicate=subchronos:molotov,distance=0..200] at @s run function subchronos:game/items/molotov/explode

# Healing Zone
    execute as @e[type=area_effect_cloud,predicate=subchronos:healing_zone,distance=0..200] at @s run function subchronos:game/items/healing_zone/gen
    execute as @e[type=marker,tag=healing_zone] at @s run function subchronos:game/items/healing_zone/tick

# C4
    execute as @e[type=item,distance=0..200,predicate=subchronos:c4] at @s run function subchronos:game/items/c4/gen
    execute as @e[type=item_display,tag=c4] at @s run function subchronos:game/items/c4/tick

# Mine
    execute as @e[type=item,distance=0..200,predicate=subchronos:mine] at @s run function subchronos:game/items/mine/gen
    execute as @e[type=marker,tag=mine] at @s run function subchronos:game/items/mine/tick

# Ninja smoke
    execute as @e[type=area_effect_cloud,predicate=subchronos:ninja_smoke,distance=0..200] at @s run function subchronos:game/items/ninja_smoke/use

# Void Allay
    execute as @a[tag=!spectating,predicate=subchronos:void_allay,scores={y=..-60}] at @s run function subchronos:game/items/void_allay/use

# Supply drop
    scoreboard players remove @a[scores={supplyDropCooldown=1..}] supplyDropCooldown 1


#Arrows
    #Explosive
        execute as @e[type=arrow,predicate=subchronos:explosive_arrow,distance=0..200] at @s run function subchronos:game/items/arrow/explosive/explode_arrow
        execute as @e[predicate=subchronos:explosive_arrow_entity,distance=0..200,tag=!spectating] at @s run function subchronos:game/items/arrow/explosive/explode_entity
    #Iron
        execute as @e[type=arrow,predicate=subchronos:iron_arrow,distance=0..200] at @s run function subchronos:game/items/arrow/iron/tick
