team remove gameInfo1
team remove gameInfo2
team remove gameInfo3
team remove gameInfo4
team add gameInfo1
team add gameInfo2
team add gameInfo3
team add gameInfo4

$execute if score .tempstartTime2 gameInfoValues matches 10.. run team join gameInfo1 §e§r$(startTimeM):$(startTimeS)
$execute if score .tempstartTime2 gameInfoValues matches ..9 run team join gameInfo1 §e§r$(startTimeM):0$(startTimeS)
team modify gameInfo1 prefix {"shadow_color":-12434878,"translate":"subchronos.game.scoreboard.starting","fallback":" Starting in: ","color":"#5cf1bf"}

$team join gameInfo2 §p§r$(playersAlive)
team modify gameInfo2 prefix {"shadow_color":-12434878,"translate":"subchronos.game.scoreboard.players","fallback":" Players alive: ","color":"#a7ee34"}

$execute if score .tempbarrelRefill2 gameInfoValues matches 10.. run team join gameInfo3 §b§r$(barrelRefillM):$(barrelRefillS)
$execute if score .tempbarrelRefill2 gameInfoValues matches ..9 run team join gameInfo3 §b§r$(barrelRefillM):0$(barrelRefillS)
team modify gameInfo3 prefix {"shadow_color":-12434878,"translate":"subchronos.game.scoreboard.barrel_refill","fallback":" Barrel refill: ","color":"#f1bd5c"}

$execute if score .temptimeExplosion2 gameInfoValues matches 10.. run team join gameInfo4 §c§r$(timeExplosionM):$(timeExplosionS)
$execute if score .temptimeExplosion2 gameInfoValues matches ..9 run team join gameInfo4 §c§r$(timeExplosionM):0$(timeExplosionS)
team modify gameInfo4 prefix {"shadow_color":-12434878,"translate":"subchronos.game.scoreboard.time_explosion","fallback":" Timed Explosion: ","color":"#fd3636"}

# ------ #

scoreboard players reset * gameInfo

scoreboard players set §c gameInfo 100
scoreboard players set §a gameInfo 1

$execute unless score .tempstartTime gameInfoValues matches -1 if score .tempstartTime2 gameInfoValues matches 10.. run scoreboard players set §e§r$(startTimeM):$(startTimeS) gameInfo 5
$execute unless score .tempstartTime gameInfoValues matches -1 if score .tempstartTime2 gameInfoValues matches ..9 run scoreboard players set §e§r$(startTimeM):0$(startTimeS) gameInfo 5

$execute unless score gameStatus gameInfoValues matches 1 run scoreboard players set §p§r$(playersAlive) gameInfo 4

$execute unless score .tempbarrelRefill gameInfoValues matches -1 if score .tempbarrelRefill2 gameInfoValues matches 10.. run scoreboard players set §b§r$(barrelRefillM):$(barrelRefillS) gameInfo 3
$execute unless score .tempbarrelRefill gameInfoValues matches -1 if score .tempbarrelRefill2 gameInfoValues matches 0..9 run scoreboard players set §b§r$(barrelRefillM):0$(barrelRefillS) gameInfo 3

$execute unless score .temptimeExplosion gameInfoValues matches -1 if score .temptimeExplosion2 gameInfoValues matches 10.. run scoreboard players set §c§r$(timeExplosionM):$(timeExplosionS) gameInfo 2
$execute unless score .temptimeExplosion gameInfoValues matches -1 if score .temptimeExplosion2 gameInfoValues matches 0..9 run scoreboard players set §c§r$(timeExplosionM):0$(timeExplosionS) gameInfo 2