#--Players alive--#
    scoreboard players set playersAlive gameInfoValues 0
    execute as @a[tag=!spectating] run scoreboard players add playersAlive gameInfoValues 1
    execute store result storage subchronos:input gameInfoScoreboard.playersAlive int 1 run scoreboard players get playersAlive gameInfoValues

#--Start timer--#
    #To seconds
        scoreboard players operation .tempstartTime gameInfoValues = startTime gameInfoValues
        scoreboard players operation .tempstartTime2 gameInfoValues = .tempstartTime gameInfoValues
    #To mins and secs
        execute store result storage subchronos:input gameInfoScoreboard.startTimeS int 1 run scoreboard players operation .tempstartTime2 gameInfoValues %= 60 const
        execute store result storage subchronos:input gameInfoScoreboard.startTimeM int 1 run scoreboard players operation .tempstartTime gameInfoValues /= 60 const

#--Barrel refill timer--#
    #To seconds
        scoreboard players operation .tempbarrelRefill gameInfoValues = barrelRefill gameInfoValues
        scoreboard players operation .tempbarrelRefill2 gameInfoValues = .tempbarrelRefill gameInfoValues
    #To mins and secs
        execute store result storage subchronos:input gameInfoScoreboard.barrelRefillS int 1 run scoreboard players operation .tempbarrelRefill2 gameInfoValues %= 60 const
        execute store result storage subchronos:input gameInfoScoreboard.barrelRefillM int 1 run scoreboard players operation .tempbarrelRefill gameInfoValues /= 60 const

#--Explosion timer--#
    #To seconds
        scoreboard players operation .temptimeExplosion gameInfoValues = timeExplosion gameInfoValues
        scoreboard players operation .temptimeExplosion2 gameInfoValues = .temptimeExplosion gameInfoValues
    #To mins and secs
        execute store result storage subchronos:input gameInfoScoreboard.timeExplosionS int 1 run scoreboard players operation .temptimeExplosion2 gameInfoValues %= 60 const
        execute store result storage subchronos:input gameInfoScoreboard.timeExplosionM int 1 run scoreboard players operation .temptimeExplosion gameInfoValues /= 60 const

function subchronos:game/scoreboard/update with storage subchronos:input gameInfoScoreboard