# Config game
function game:reset

bossbar set generation visible false
title @a actionbar ""

# Clear lobby
kill @e[tag=lobby]

# -------- Specific
# Return meta coins if expended
scoreboard players set #tmp dungeon 5
scoreboard players operation floor dungeon *= #tmp dungeon
scoreboard players operation floor dungeon -= #tmp dungeon
scoreboard players operation mcoins shop += floor dungeon

# Clear
execute at @e[tag=center] run function rooms:0_clear/1_clear
kill @e[tag=tutorial_obj]
kill @e[tag=boss_warp]
kill @e[type=item]
tp @e[tag=EB] 0 -1 0

# Markers
function tutorial:place

# Title
title @a title [{"text":">> ","color":"dark_red","bold":true},{"translate":"floor","color":"gold"},{"text":" 0","color":"gold"},{"text":" <<","color":"dark_red"}]
title @a subtitle {"translate":"tutorial","color":"gray","bold":true}
title @a times 10 60 10

# Reset
scoreboard players operation game state = #in_run state
scoreboard players set floor dungeon 0

# warp
tp @a 0 16 0 0 0
playsound custom.player.tp ambient @a 0 16 0 0.5