summon falling_block ~ ~-1.2 ~ {BlockState:{Name:"minecraft:ice"},Time:-13,DropItem:0b,Motion:[0.0,0.31,0.0],Tags:["unspellable"]}
playsound block.glass.break hostile @a ~ ~ ~ .3 0.5

execute unless entity @e[tag=ice_snake_rem,distance=..0.75,limit=1,nbt={Age:0}] run summon area_effect_cloud ~ ~ ~ {Tags:["obj","unspellable","ice_snake_rem","init"],Duration:20}

# Particle
particle block ice ~ ~.2 ~ .5 .5 .5 .1 6 force
particle falling_dust ice ~ ~.1 ~ .4 .3 .4 .1 6 force

# Effects
scoreboard players set duration n_effects 70
execute as @e[tag=!unspellable,type=!#no_interaction_p,distance=..1.2] run function effects:freeze/give
scoreboard players add @e[tag=!unspellable,type=!#no_interaction_p,distance=..1] damage 30

# Move
function mrcd:ray_tick
# Gavity for the arch trajectory
execute if score @s[tag=!mrcd_touch_y_plus] mrcd_y0 matches -19999.. run scoreboard players remove @s mrcd_y0 50
execute if score @s[tag=!mrcd_touch_y_plus] mrcd_y0 matches ..-20001 run scoreboard players set @s mrcd_y0 -20000

tp @s[tag=mrcd_touch_y_plus] ~ ~.15 ~
execute if entity @s[tag=mrcd_touch_y_plus] run scoreboard players set @s mrcd_y0 0
kill @s[tag=mrcd_touch_edge,tag=!mrcd_touch_y_plus]
