# base = 30%   luck(100%) = 33%    curse = 5%   -> max drop = 68
scoreboard players operation % rng = global luck
scoreboard players set #tmp rng 3
scoreboard players operation % rng /= #tmp rng
scoreboard players add % rng 30
execute if predicate 0_enemy_boss:mob_death/cursed run scoreboard players add % rng 5
execute if score % rng matches 101.. run scoreboard players set % rng 100
execute if predicate rng:percentage_check run function items:mob_death/coins/drop_copper

# base = 3%   luck(100%) = 10%    curse = 2%   -> max drop = 14
scoreboard players operation % rng = global luck
scoreboard players set #tmp rng 10
scoreboard players operation % rng /= #tmp rng
scoreboard players add % rng 3
execute if predicate 0_enemy_boss:mob_death/cursed run scoreboard players add % rng 2
execute if score % rng matches 101.. run scoreboard players set % rng 100
execute if predicate rng:percentage_check run function items:shop/summon/silver_coin

# base = 1%   luck(100%) = 5%    curse = 1%   -> max drop = 7
scoreboard players operation % rng = global luck
scoreboard players set #tmp rng 20
scoreboard players operation % rng /= #tmp rng
scoreboard players add % rng 1
execute if predicate 0_enemy_boss:mob_death/cursed run scoreboard players add % rng 1
execute if score % rng matches 101.. run scoreboard players set % rng 100
execute if predicate rng:percentage_check run function items:shop/summon/gold_coin
