#Tornado rotation
tp @s ~ ~ ~ ~15 ~

#---Tornado Traction ---
execute as @e[distance=..6,type=!player,tag=!unspellable] at @s run tp @s ~ ~ ~ facing entity @e[limit=1,sort=nearest,tag=obj,tag=tornado]
execute as @e[distance=..6,type=!player,tag=!unspellable] at @s run function items:obj/tornado/pull

# ------ Damage --------
execute unless score @s countdown matches ..0 unless score @s countdown matches 0.. run scoreboard players set @s countdown 15
execute if score @s countdown matches 0 run scoreboard players add @e[distance=..4,tag=!unspellable,type=!#no_interaction_p] damage 200

#---Tornado Particles---
particle cloud ^.5 ^.2 ^ 0 0 0 0 1 force
particle cloud ^ ^.9 ^-.8 0 0 0 0 1 force
particle cloud ^-1 ^1.6 ^ 0 0 0 0 1 force
particle cloud ^ ^2.3 ^1.2 0 0 0 0 1 force
particle cloud ^1.4 ^3 ^ 0 0 0 0 1 force
particle smoke ~ ~ ~ 3 2 3 .4 15 force
particle cloud ~ ~ ~ 3 2 3 .4 5 force
