# Next Sound
execute if predicate entity/hurt run playsound custom.druid.hurt hostile @a ~ ~ ~
execute if predicate entity/hurt run function 0_enemy_boss:sound_cooldown/reset_by_hurt

execute if score @s EB_next_sound matches ..0 run function 0_enemy_boss:sound_cooldown/generic_long
execute if score @s EB_next_sound matches 1 run playsound custom.druid.ambient hostile @a ~ ~ ~

# Next Attack
execute if entity @s[scores={EB_next_attack=..0},tag=!attacking] run function bosses:druid/attk/next
execute if entity @s[tag=attacking,tag=!attk_choosen] run function bosses:druid/attk/choose

# Attacks
execute if entity @s[tag=spinning_stones,tag=jumping] if predicate entity/on_ground run function bosses:druid/spinning_stones/summon
execute if entity @s[tag=spinning_stones,tag=!jumping] run function bosses:druid/jump
execute if entity @s[tag=throw_stones] run function bosses:druid/throw_stones/main
execute if entity @s[tag=multiple_roots,tag=jumping] if predicate entity/on_ground run function bosses:druid/multiple_roots/summon
execute if entity @s[tag=multiple_roots,tag=!jumping] run function bosses:druid/jump
execute if entity @s[tag=summon_ent] run function bosses:druid/summon_ent/main
