# Clear
execute at @e[tag=center] run function rooms:0_clear/1_clear
kill @e[tag=tutorial_obj]
kill @e[tag=boss_warp]
kill @e[type=item]
tp @e[tag=E+B] 0 -1 0
bossbar set generation visible false

# Structures
setblock -6 12 -7 structure_block{mode:"LOAD",name:"tutorial/00"}
setblock -6 13 -7 redstone_block
setblock -6 12 20 redstone_block
setblock -5 12 51 redstone_block
setblock -5 12 75 redstone_block

# Markers
function lobby:tutorial/1_void
function lobby:tutorial/2_middle
function lobby:tutorial/3_armory
function lobby:tutorial/4_mana_kills
function lobby:tutorial/5_boss

execute as @e[tag=tutorial_obj,tag=!holder] run data merge entity @s {CustomNameVisible:1b,NoGravity:1b,Small:1b,Invisible:1b,Invulnerable:1b}

# Title
title @a title [{"text":">> ","color":"dark_red","bold":true},{"text":"Floor 0","color":"gold"},{"text":" <<","color":"dark_red"}]
title @a subtitle {"text":"Tutorial","color":"gray","bold":true}
title @a times 10 60 10

# Reset
scoreboard players set game state 3
scoreboard players set floor dungeon 0
execute as @a run gamemode adventure
effect clear @a
function game:reset

# warp
tp @a 0 16 0 0 0

# Inventory
execute as @a run function lobby:warp/inventory
