
# -> Get item used
execute on target run \
    function overly_realistic:general/custom_blocks/wooden_drum/player_interact_with_wooden_drum

# -> If player played the drum with a bone then operate
execute if items entity 00000001-0000-002b-0000-00010000002b contents bone run \
    return run \
        function overly_realistic:general/custom_blocks/wooden_drum/drum_use/use_with_bone

# -> If player played the drum with a stick then operate
execute if items entity 00000001-0000-002b-0000-00010000002b contents stick run \
    return run \
        function overly_realistic:general/custom_blocks/wooden_drum/drum_use/use_with_stick


# -> Sneaking sound
execute if score #or.globalized_drum_use_while_shifting OverlyRealistic.General.ArbitraryData matches 1 run \
    return run \
        playsound overlyrealistic:block.wooden_drum.drum_use block @a ~ ~ ~ 1 1.25

# -> Normal sound
playsound overlyrealistic:block.wooden_drum.drum_use block @a ~ ~ ~ 1 1
