
# -> Set ID
scoreboard players set #or.basket_water_place_type OverlyRealistic.General.ArbitraryData 2

# -> Set liquid type
scoreboard players set @s OverlyRealistic.World.BasketLiquidType 2

# -> Set liquid model
execute on passengers run \
    item modify entity @s[tag=OverlyRealistic.Block.Basket] contents overly_realistic:basket/liquid_model/set_dirty_water

# -> Operate on player
execute on target \
    if items entity @s[gamemode=!creative] weapon.mainhand *[custom_data~{or_bucket_specific:"iron_bucket"}] run \
        return run \
            loot replace entity @s weapon.mainhand loot overly_realistic:items/iron_bucket_empty
execute on target \
    if items entity @s[gamemode=!creative] weapon.mainhand *[custom_data~{or_bucket_specific:"wooden_bucket"}] run \
        return run \
            loot replace entity @s weapon.mainhand loot overly_realistic:items/wooden_bucket_empty
execute on target \
    if items entity @s[gamemode=!creative] weapon.mainhand potion run \
        return run \
            item replace entity @s weapon.mainhand with glass_bottle[max_stack_size=1]
