
# -> Sound
playsound block.wool.break block @a ~ ~ ~ 1 1
playsound block.wool.break block @a ~ ~ ~ 1 1
playsound block.wool.break block @a ~ ~ ~ 1 2

# -> Drop item
execute if entity @s[tag=OverlyRealistic.Block.Bellow_IsCompressed] \
    unless entity @p[tag=OverlyRealistic.Player.BrokeCustomBlock, gamemode=creative, distance=..8] run \
        loot spawn ~ ~ ~ loot overly_realistic:blocks/bellow_closed
execute unless entity @s[tag=OverlyRealistic.Block.Bellow_IsCompressed] \
    unless entity @p[tag=OverlyRealistic.Player.BrokeCustomBlock, gamemode=creative, distance=..8] run \
        loot spawn ~ ~ ~ loot overly_realistic:blocks/bellow

# -> Set PickupDelay
execute align xyz \
    as @e[type=item,dx=0,dy=0,dz=0] \
    if items entity @s contents allay_spawn_egg[custom_data~{IsCustomBlock: "bellow"}] run \
        data modify entity @s PickupDelay set value 20

# -> Remove display
execute on passengers \
    on passengers run \
        kill @s
execute on passengers run \
    kill @s

# -> Remove interaction
kill @s
