
# -> Set success
scoreboard players set #or.wooden_water_bucket_success OverlyRealistic.General.ArbitraryData 1

# -> Particle
execute align xyz run \
    particle splash ~0.5 ~0.5 ~0.5 0.25 0.25 0.25 0.1 5 normal @a

# -> Set dirty water, for if block is a cauldron
scoreboard players set #or.wooden_bucket_acquire_water_type OverlyRealistic.General.ArbitraryData 1

# -> Cauldron
execute if block ~ ~ ~ water_cauldron run \
    return run \
        setblock ~ ~ ~ cauldron

# -> If biome is an ocean then set sea water
execute if biome ~ ~ ~ #overly_realistic:has_sea_water run \
    scoreboard players set #or.wooden_bucket_acquire_water_type OverlyRealistic.General.ArbitraryData 3

# -> Water
execute if block ~ ~ ~ water run \
    return run \
        setblock ~ ~ ~ air
