
# -> On item-dependent RNG, return
$execute unless predicate {condition:"random_chance",chance:$(cure_probability)} \
    unless score #or.setting.implicit_cure_chance OverlyRealistic.Settings.ArbitrarySetting matches 1 run \
        return fail

# -> If symbol 1 is curable then cure it
$execute if score @s OverlyRealistic.Player.Status_IllnessType_1 matches $(cure_ingridient_1) run \
    scoreboard players set @s OverlyRealistic.Player.Status_IllnessType_1 0

# -> If symbol 2 is curable then cure it
$execute if score @s OverlyRealistic.Player.Status_IllnessType_2 matches $(cure_ingridient_2) run \
    scoreboard players set @s OverlyRealistic.Player.Status_IllnessType_2 0

# -> If symbol 3 is curable then cure it
$execute if score @s OverlyRealistic.Player.Status_IllnessType_3 matches $(cure_ingridient_3) run \
    scoreboard players set @s OverlyRealistic.Player.Status_IllnessType_3 0

# -> If all symbols = 0 then cure illness entirely
execute if score @s OverlyRealistic.Player.Status_IllnessType_1 matches 0 \
    if score @s OverlyRealistic.Player.Status_IllnessType_2 matches 0 \
    if score @s OverlyRealistic.Player.Status_IllnessType_3 matches 0 run \
        function overly_realistic:players/illness/clear_illness
