
# -> Check for dirty foods in water
execute if items entity @s contents *[custom_data~{or_food_is_dirty:1b}] run \
    return run \
        execute if block ~ ~ ~ #overly_realistic:is_water run \
            function overly_realistic:general/food/food_dirtyness/clean_food_in_water

# -> Check for dirt in water
execute if items entity @s contents dirt run \
    return run \
        execute if block ~ ~ ~ #overly_realistic:is_water run \
            item modify entity @s contents overly_realistic:misc/dirt_to_mud

# -> Check for dirty clothes
execute if items entity @s contents *[custom_data~{IsDirty:true}] run \
    return run \
        execute if block ~ ~ ~ #overly_realistic:is_water run \
            item modify entity @s contents overly_realistic:armor/clean_armor

# -> Tag item
tag @s add OverlyRealistic.CheckedItemDropSlow
